begin parameters
L0 200	# Number of ligand molecules
R0 200	# Number of receptor molecules
A0 50		# Number of adaptor molecules
kp1 0.01	# Ligand-receptor association
km1  1		# Ligand-receptor dissociation
kp2  1		# Dimer formation
km2  1		# Dimer dissociation
p1  10		# Receptor transphosphorylation
d1   5		# Receptor dephosphorylation
kpA  0.1	# Adaptor-receptor association
kmA  0.1	# Adaptor-receptor dissociation
p2   10		# Adaptor transphosphorylation
d2    5		# Adaptor dephosphorylation
end parameters

begin molecule types
L(r)
R(l,d,Y~U~P)
A(SH2,Y~U~P)
end molecule types

begin seed species
L(r)       L0
R(l,d,Y~U) R0
A(SH2,Y~U) A0
end seed species


begin observables
  Molecules R_dim  R(d!+)
  Molecules R_phos R(Y~P!?)
  Molecules A_R    A(SH2!1).R(Y~P!1)
  Molecules A_phos A(Y~P!?)
  Molecules A_tot  A()     # Total of A
end observables

begin reaction rules
  # Ligand-receptor binding
L(r) + R(l,d) <-> L(r!1).R(l!1,d) kp1, km1
  # Receptor aggregation
R(l!+,d) + R(l!+,d) <-> \
             R(l!+,d!2).R(l!+,d!2) kp2, km2
  # Receptor transphosphorylation
 R(d!+,Y~U) -> R(d!+,Y~P) p1
  # Receptor dephosphorylation 
 R(Y~P) -> R(Y~U) d1
  # Adaptor association
 R(Y~P) + A(SH2) <-> R(Y~P!1).A(SH2!1) kpA, kmA
  # Adaptor transphosphorylation
 A(Y~U).A() -> A(Y~P).A() p2
  # Adaptor dephosphorylation
 A(Y~P) -> A(Y~U) d2
end reaction rules


generate_network({overwrite=>1});
writeSBML();
simulate_ode({suffix=>ode,t_end=>5,n_steps=>50});
#simulate_ssa({suffix=>ssa,t_end=>5,n_steps=>50});